cfmailparam

Description

Attaches a file or adds a header to an e-mail message.

History

ColdFusion MX 6.x: Added the Disposition and ContentID attributes. ColdFusion MX 6.1: Added the type attribute.

Syntax

<cfmail  
    to = "recipient" 
    subject = "message subject" 
    from = "sender" 
        more attributes... > 
    <cfmailparam  
        contentID = "content ID" 
        disposition = "disposition type"> 
        file = "filename"  
        type ="media type" 
 
OR 
 
    <cfmailparam  
        name = "header name" 
         value = "header value"> 
    ... 
</cfmail>

Note: You can specify this tag’s attributes in an attributeCollection attribute whose value is a structure. Specify the structure name in the attributeCollection attribute and use the tag’s attribute names as structure keys.

Attributes

Attribute	Description	Required	Default
contentID	The Identifier for the attached file. This ID must be globally unique and is used to identify the file in an IMG or other tag in the mail body that references the file content.	Optional
disposition	How the attached file is to be handled. Can be one of the following: attachment: presents the file as an attachment. inline: displays the file contents in the message.	Optional	attachment
file	Attaches a file in a message. Mutually exclusive with name attribute. The file is MIME encoded before sending.	Required if you do not specify name attribute
name	Name of header. Case-insensitive. Mutually exclusive with file attribute.	Required if you do not specify file attribute
type	The MIME media type of the file. Not used with the name attribute. Can be a valid MIME media type or one of the following: text: specifies text/plain type. plain: specifies text/plain type. html: specifies text/html type. If you specify the type, the value you specify becomes the content type header; otherwise, ColdFusion generates the content type header. Note: For a list of all registered MIME media types, see www.iana.org/assignments/media-types/.	Optional
value	Value of the header. Not used with the file attribute.	Optional

Usage

This tag attaches a file or adds a header to an e-mail message. It can only be used in the cfmail tag. You can use multiple cfmailparam tags within a cfmail tag.
You can use this tag to include a file, such as an image, in an HTML mail message. The file can be displayed inline in an HTML message, or as an attachment, as Example 2 shows. To include multiple files, use multiple cfmailparam tags.

Example

Example 1: This view-only example uses the cfmailparamtag to add a header to a message, attach files, and to return a receipt to the sender.

<cfmail from = "peter@domain.com" To = "paul@domain.com"  
    Subject = "See Important Attachments and Reply"> 
    <cfmailparam name = "Importance" value = "High"> 
    Please review the new logo. Tell us what you think. 
    <cfmailparam file = "c:\work\readme.txt" type="text/plain"> 
    <cfmailparam file = "c:\work\logo.gif" type="image/gif"> 
    <cfmailparam name="Disposition-Notification-To" value="peter@domain.com"> 
</cfmail>

Example 2: This view-only example displays an image in the body of an HTML message.

<cfmail type="HTML" 
        to = "#form.mailto#" 
        from = "#form.mailFrom#" 
        subject = "Sample inline image"> 
    <cfmailparam file="C:\Inetpub\wwwroot\web.gif"  
        disposition="inline"  
        contentID="image1"> 
    There should be an image here</p> 
    <img src="cid:image1"> 
    After the picture</p> 
</cfmail>

cfmldocs