Generates an HTTP request and handles the response from the server.

Internet Protocol Tags

cfftp cfhttpparam cfldap cfmail cfpop getHttpRequestData

ColdFusion 8: Added the clientCert and clientCertPassword attributes. ColdFusion MX 7.01: Added the “never” value of the getAsBinary attribute. ColdFusion MX 7: Added the result attribute, which allows you to specify an alternate variable in which to receive a result. ColdFusion MX 6.1: Added support for the following methods: HEAD, PUT, DELETE, OPTIONS, TRACE. Added multipart, getAsBinary, proxyUser, and proxyPassword attributes. Changed httpparam behavior: all operations can have httpparam tags. Added the cfhttp.errorDetail return variable. Modified response body content types considered to be text. Changed behavior for multiple headers: multiple headers of the same type are returned in an array. Added support for HTTPS proxy tunneling. Fixed bugs in code and documentation. ColdFusion MX: Added the charset and firstrowasheaders attributes. Changed Secure Sockets Layer (SSL) support: ColdFusion uses the Sun JSSE library, which supports 128-bit encryption, to support SSL.

<cfhttp  
    url = "server URL" 
    charset = "character encoding" 
    clientCert = "filename" 
    clientCertPassword = "password" 
    columns = "query columns" 
    delimiter = "character" 
    file = "filename" 
    firstrowasheaders = "yes|no" 
    getAsBinary = "auto|yes|no|never" 
    method = "method name" 
    multipart = "yes|no" 
    name = "query name" 
    password = "password" 
    path = "path" 
    port = "port number" 
    proxyServer = "host name" 
    proxyPort = "port number" 
    proxyUser = "username" 
    proxyPassword = "password" 
    redirect = "yes|no" 
    resolveURL = "yes|no" 
    result = "result name" 
    textQualifier = "character" 
    throwOnError = "yes|no" 
    timeout = "time-out period in seconds" 
    username = "username" 
    userAgent = "user agent"> 
 
    cfhttpparam tags [optional for some methods] 
 
</cfhttp>

Note: You can specify this tag’s attributes in an attributeCollection attribute whose value is a structure. Specify the structure name in the attributeCollection attribute and use the tag’s attribute names as structure keys.

The cfhttp tag is a general-purpose tool for creating HTTP requests and handling the returned results. It enables you to generate most standard HTTP request types. You use embedded cfhttpparam tags to specify request headers and body content.
When ColdFusion receives a response to a cfhttp request, it can put the response body (if any) in a file or the cfhttp.FileContent string variable. If the body text is structured as a result set, ColdFusion can put the body text in query object. You can also access the values of all returned headers and specify how to handle error status and redirections, and specify a time-out to prevent requests from hanging.
The HTTP protocol is the backbone of the World Wide Web and is used for every web transaction. Because the cfhttp tag can generate most types of requests, it provides significant flexibility. Possible uses include:
Interacting with dynamic web sites and services that are not available as web services. (Use the cfinvoke tag to access SOAP web services.)
Getting the contents of an HTML page or other file such as an image on a web server for use in your CFML page or storage in a file.
Sending a secure request to a server by specifying the https protocol in the url attribute.
Using the POST method to send a multipart/form-data style post to any URL that can handle such data and return results, including CGI executables or even other ColdFusion pages.
Using the PUT method to upload files to a server that does not accept FTP requests.
This tag can, and for PUT and POST requests must, have a body that contains cfhttpparam tags. If this tag has cfhttpparam tags, it must have a </cfhttp> end tag.
To use HTTPS with the cfhttp tag, you might need to manually import the certificate for each web server into the keystore for the JRE that ColdFusion uses. This procedure should not be necessary if the certificate is signed (issued) by an authority that the JSSE (Java Secure Sockets Extension) recognizes (for example, Verisign); that is, if the signing authority is in the cacerts already. However, you might need to use the procedure if you are issuing SSL (secure sockets layer) certificates yourself.

<!--- This example displays the information provided by  
    the Designer & Developer Center XML feed, 
    http://www.adobe.com/devnet/resources/_resources.xml  
    See http://www.adobe.com/devnet/articles/xml_resource_feed.html  
    for more information on this feed. ---> 
 
<!--- Set the URL address. ---> 
<cfset urlAddress="http://www.adobe.com/devnet/resources/_resources.xml"> 
 
<!--- Use the CFHTTP tag to get the file content represented by urladdress.  
        Note that />, not an end tag, terminates this tag. ---> 
<cfhttp url="#urladdress#" method="GET" resolveurl="Yes" throwOnError="Yes"/> 
 
<!--- Parse the XML and output a list of resources. ---> 
<cfset xmlDoc = XmlParse(CFHTTP.FileContent)> 
<!--- Get the array of resource elements, the xmlChildren of the xmlroot. ---> 
<cfset resources=xmlDoc.xmlroot.xmlChildren> 
<cfset numresources=ArrayLen(resources)> 
 
<cfloop index="i" from="1" to="#numresources#"> 
    <cfset item=resources[i]> 
    <cfoutput> 
        <strong><a href=#item.url.xmltext#>#item.title.xmltext#</strong></a><br> 
        <strong>Author</strong>&nbsp;&nbsp;#item.author.xmltext#<br> 
        <strong>Applies to these products</strong><br> 
        <cfloop index="i" from="4" to="#arraylen(item.xmlChildren)#"> 
            #item.xmlChildren[i].xmlAttributes.Name#<br> 
        </cfloop> 
        <br> 
    </cfoutput> 
</cfloop>